$               This information is provided by the
$                       Aptronix FuzzyNet
$                 http://www.aptronix.com/fuzzynet 
$                  email fuzzynet@aptronix.com 
$               Aptronix may also be reached by phone
$                       at 408-261-1898 or
$                       FAX at 408-490-2729
$
$
$ NAME: FUZZBEAM.FIL
$ Date Created: 4-23-1993
$ Date Modified: 6-21-1993
$ Copyright,1993 Ted Heske 

$Header
fiu tvfi(min max)*16;                                 $ FIDE inference unit
invar bw "microns":  100 () 2500
	[                               
	  Small(@100,1.0,@160,1.0,@340,0),       
	  Medium(@160,0,@350,1.0,@500,0),
	  Ideal(@360,0,@370,1.0,@2500,1.0),
	  Large(@380,0, @600,1.0,@2500,1.0)
	];                                 
invar slope "microns/step" : -15 () 15
	[
	  NL(@-15,1.0,@-3,0.0),
	  NS(@-6,0.0,@-3,1.0,@0,0.0),
	   Z(@-2,0.0,@0,1.0,@2,0.0),
	  PS(@0,0.0,@3,1.0,@6,0.0),
	  PL(@3,0.0,@15,1.0)
	];
outvar steps "motor steps" : 1 () 60 * (        $ steps is an output variable
		  S = 1,
	  M = 15,
	  L = 60
	);
outvar done : 0 () 1 * (    $ quit is another output variable
		  No = 0,
	  Yes = 1
	);                              $ end of output labels

$ rules start here:

$Examples of Macro Rules
if bw is { Small,  Medium,  Large}
   and slope is { { NL, NS, Z, PS, PL }}
   then steps is {  {L, L, M, M, M },
				{L, M, S, S, S },
				{L, L, L, L, L }  };
$ The above macro-rule consists of 15 rules (a complete rule table)

if bw is Ideal and slope is NL then done is No;
if bw is Ideal and slope is NS then done is No;
if bw is Ideal and slope is Z then done is No;
if bw is Ideal and slope is PS then done is Yes;
if bw is Ideal and slope is PL then done is Yes;

end