$               This information is provided by the
$                       Aptronix FuzzyNet
$                 http://www.aptronix.com/fuzzynet 
$                  email fuzzynet@aptronix.com 
$               Aptronix may also be reached by phone
$                       at 408-261-1898 or
$                       FAX at 408-490-2729
$
$
$ FILENAME:	washmach\wash1.fil
$ DATE: 	July 23, 1992
$ UPDATE:	July 29, 1992
$ AUTHOR:	W. Zhang, Aptronix, Inc.
$ REFERENCE: 	P94-98, BK(J), M.Nagamachi, 1991, KAIBUNDO

$ CONTROLLER for Washing Machine: Two inputs, one output, open-loop control
$ INPUT(S): 	dirtness_of_clothes, type_of_dirt
$ OUTPUT(S): 	wash_time

$ FIU HEADER

fiu tvfi (min max) *8;

$ DEFINITION OF INPUT VARIABLE(S)

invar dirtness_of_clothes "degree" : 0 () 100 [
      Large  (@50, 0,  @100,  1),
      Medium (@0,  0,  @50,   1,  @100,  0),
      Small  (@0,  1,  @50,   0)
    ]; 

invar type_of_dirt "degree" : 0 () 100 [
      Greasy    (@50,  0,  @100,  1),
      Medium    (@0,   0,  @50,   1,  @100,  0),
      NotGreasy (@0,   1,  @50,   0)
    ];	

$ DEFINITION OF OUTPUT VARIABLE(S)

outvar wash_time "minute" : 0 () 60 * (
	VeryLong  = 60,      
	Long      = 40,
	Medium    = 20,
        Short     = 12,
	VeryShort = 8
    );

$ RULES

if dirtness_of_clothes is Large  and type_of_dirt is Greasy     then wash_time is VeryLong;
if dirtness_of_clothes is Medium and type_of_dirt is Greasy     then wash_time is Long;
if dirtness_of_clothes is Small  and type_of_dirt is Greasy     then wash_time is Long;

if dirtness_of_clothes is Large  and type_of_dirt is Medium     then wash_time is Long;
if dirtness_of_clothes is Medium and type_of_dirt is Medium     then wash_time is Medium;
if dirtness_of_clothes is Small  and type_of_dirt is Medium     then wash_time is Medium;

if dirtness_of_clothes is Large  and type_of_dirt is NotGreasy  then wash_time is Medium;
if dirtness_of_clothes is Medium and type_of_dirt is NotGreasy  then wash_time is Short;
if dirtness_of_clothes is Small  and type_of_dirt is NotGreasy  then wash_time is VeryShort
end